/*
 * Copyright 2011, Blender Foundation.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * as published by the Free Software Foundation; either version 2
 * of the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software Foundation,
 * Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
 */

#include "stdosl.h"
#include "node_texture.h"

/* Gradient */

float gradient(point p, string type)
{
	float x, y, z;
	
	x = p[0];
	y = p[1];
	z = p[2];

	float result = 0.0;

	if (type == "Linear") {
		result = x;
	}
	else if (type == "Quadratic") {
		float r = max(x, 0.0);
		result = r * r;
	}
	else if (type == "Easing") {
		float r = min(max(x, 0.0), 1.0);
		float t = r * r;
		
		result = (3.0 * t - 2.0 * t * r);
	}
	else if (type == "Diagonal") {
		result = (x + y) / 2.0;
	}
	else if (type == "Radial") {
		result = atan2(y, x) / (2.0 * M_PI) + 0.5;
	}
	else {
		float r = max(1.0 - sqrt(x * x + y * y + z * z), 0.0);

		if (type == "Quadratic Sphere")
			result = r * r;
		else if (type == "Spherical")
			result = r;
	}

	return result;
}

shader node_gradient_texture(
	int use_mapping = 0,
	matrix mapping = matrix(0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0),
	string Type = "Linear",
	point Vector = P,
	output float Fac = 0.0,
	output color Color = color(0.0, 0.0, 0.0))
{
	point p = Vector;

	if (use_mapping)
		p = transform(mapping, p);

	Fac = gradient(p, Type);
	Color = color(Fac, Fac, Fac);
}

